er object error 'ASP 0177 : 800401f3' Server.CreateObject Failed

I am fairly new to asp, and our coder abandoned us. Our server recently went down, and upon uploading a full backup of the site, we are getting this error when we attempt to send from any form on the site.

er object error 'ASP 0177 : 800401f3'

Server.CreateObject Failed

/scripts/_INCappEmail_.asp, line 99

800401f3

Below is the code from the _INCappEmail_.asp page, line 99 is highlighted in red.
<%
'*************************************************************************
' DO NOT MODIFY THIS SCRIPT IF YOU WANT UPDATES TO WORK!
' Function : Sends email
' Product : CandyPress Store Frontend
' Version : 2.5
' Modified : February 2004
' Copyright: Copyright (C) 2004 CandyPress.Com
' See "license.txt" for this product for details regarding
' licensing, usage, disclaimers, distribution and general
' copyright requirements. If you don't have a copy of this
' file, you may request one at webmaster@candypress.com
'*************************************************************************

'*************************************************************************
'Forward email send request to appropriate component
'*************************************************************************
Function sendMail(fromName, fromEmail, toEmail, subject, body, contType)

'Ignore email errors if not in debug mode
if UCase(debugMode) <> "Y" then
on error resume next
end if

select case mailComp

case "1" 'JMail
call JMail(fromName, fromEmail, toEmail, subject, body, contType)

case "2" 'CDONTS
call CDONTS(fromName, fromEmail, toEmail, subject, body, contType)

case "3" 'Persits ASPEmail
call PASPEmail(fromName, fromEmail, toEmail, subject, body, contType)

case "4" 'ServerObjects ASPMail
call SOASPMail(fromName, fromEmail, toEmail, subject, body, contType)

case "5" 'Bamboo SMTP
call bamboo(fromName, fromEmail, toEmail, subject, body, contType)

case "6" 'CDOSYS
call CDOSYS(fromName, fromEmail, toEmail, subject, body, contType)

end select

on error goto 0

end Function

'JMail (v4.3)
Function JMail(fromName, fromEmail, toEmail, subject, body, contType)
dim mail,I
set mail = server.CreateObject("JMail.Message")
'mail.Charset = "iso-2022-jp"
'mail.ContentTransferEncoding = "quoted-printable"
mail.From = fromEmail
mail.FromName = fromName
mail.FromDept = fromDept
mail.silent = false
mail.Subject = subject
mail.Body = body
if contType = 1 then 'Send HTML Email
mail.ContentType = "text/html"
end if
if isArray(toEmail) then 'Send Multiple Emails
for I = 0 to Ubound(toEmail)
if len(toEmail(I)) > 0 then
mail.ClearRecipients()
mail.AddRecipient toEmail(I)
mail.Send(pSmtpServer)
end if
next
else 'Send Single Email
mail.AddRecipient toEmail
mail.Send(pSmtpServer)
end if
set mail = nothing
end Function

'CDONTS
'Note : After the "Send" method, the "NewMail" object becomes invalid.
' We therefore have to create the "NewMail" object for each email.
Function CDONTS(fromName, fromEmail, toEmail, subject, body, contType)
dim mail,I
if isArray(toEmail) then 'Send Multiple Emails
for I = 0 to Ubound(toEmail)
if len(toEmail(I)) > 0 then
Set mail = Server.CreateObject ("CDONTS.NewMail")
if contType = 1 then 'Send HTML Email
mail.BodyFormat = 0
mail.MailFormat = 0
end if
mail.Send fromEmail & " (" & fromName & fromDept &")", toEmail(I), subject, body
set mail = nothing
end if
next
else 'Send Single Email
Set mail = Server.CreateObject ("CDONTS.NewMail")
if contType = 1 then 'Send HTML Email
mail.BodyFormat = 0
mail.MailFormat = 0
end if
mail.Send fromEmail & " (" & fromName &")", toEmail, subject, body
set mail = nothing
end if
end Function

'Persits ASP Email
Function PASPEmail(fromName, fromEmail, toEmail, subject, body, contType)
dim mail,I
set mail = server.CreateObject("Persits.MailSender")
'mail.Charset = "iso-2022-jp"
'mail.ContentTransferEncoding = "quoted-printable"
mail.Host = pSmtpServer
mail.From = fromEmail
mail.FromName = fromName
mail.FromDept = fromDept
mail.Subject = subject
mail.Body = body
if contType = 1 then 'Send HTML Email
mail.IsHTML = True
end if
if isArray(toEmail) then 'Send Multiple Emails
for I = 0 to Ubound(toEmail)
if len(toEmail(I)) > 0 then
mail.Reset
mail.AddAddress toEmail(I)
mail.Send
end if
next
else 'Send Single Email
mail.AddAddress toEmail
mail.Send
end if
set mail = nothing
end Function

'ServerObjects ASPMail
Function SOASPMail(fromName, fromEmail, toEmail, subject, body, contType)
dim mail,I
set mail = server.CreateObject("SMTPsvg.Mailer")
mail.RemoteHost = pSmtpServer
mail.FromAddress = fromEmail
mail.FromName = fromName
mail.FromDept = fromDept
mail.Subject = subject
mail.BodyText = body
if contType = 1 then 'Send HTML Email
mail.ContentType = "text/html"
end if
if isArray(toEmail) then 'Send Multiple Emails
for I = 0 to Ubound(toEmail)
if len(toEmail(I)) > 0 then
mail.ClearRecipients
mail.AddRecipient "", toEmail(I)
mail.SendMail
end if
next
else 'Send Single Email
mail.AddRecipient "", toEmail
mail.SendMail
end if
set mail = nothing
end Function

'Bamboo SMTP
Function bamboo(fromName, fromEmail, toEmail, subject, body, contType)
dim mail,I
set mail = Server.CreateObject("Bamboo.SMTP")
mail.Server = pSmtpServer
mail.From = fromEmail
mail.FromName = fromName
mail.FromDept = fromDept
mail.Subject = subject
mail.Message = body
if contType = 1 then 'Send HTML Email
mail.ContentType = "text/html"
end if
if isArray(toEmail) then 'Send Multiple Emails
for I = 0 to Ubound(toEmail)
if len(toEmail(I)) > 0 then
mail.Rcpt = toEmail(I)
mail.Send
end if
next
else 'Send Single Email
mail.Rcpt = toEmail
mail.Send
end if
set mail = nothing
end Function

'CDOSYS
Function CDOSYS(fromName, fromEmail, toEmail, subject, body, contType)
dim mail,conf,I

'Configure the server
Set conf = Server.CreateObject("CDO.Configuration")
conf.Fields.Item("sendusing")= 2
conf.Fields.Item("smtpserver") = pSmtpServer
conf.Fields.Item("smtpconnectiontimeout") = 30
conf.Fields.Item("smtpserverport") = 25
conf.Fields.Update

'Send email
Set mail = Server.CreateObject("CDO.Message")
mail.Configuration = conf
'mail.BodyPart.Charset = "iso-2022-jp"
'mail.BodyPart.ContentTransferEncoding = "quoted-printable"
mail.From = fromName & " " & fromDept &" <" & fromEmail & ">"
mail.Subject = fromDept
if contType = 1 then 'Send HTML Email
mail.HTMLBody = body
else
mail.TextBody = body
end if
if isArray(toEmail) then 'Send Multiple Emails
for I = 0 to Ubound(toEmail)
if len(toEmail(I)) > 0 then
mail.To = toEmail(I)
mail.Send
end if
next
else 'Send Single Email
mail.To = toEmail
mail.Send
end if

'Clean up
set mail = nothing
set conf = nothing

end Function
%>

I tried searching for an explanation of this error before posting, but i found nothing that deals with coding like ours. Any advice is appreciated.

 

may because CDONTS for NT

your are using IIS ... so do not mixed

 

Try using CDOSYS. CDONTS is obsolete.

From the candypress support forum I found these instructions for using CDOSYS:
Under Admin | Store Configuration | Email Settings | Select CDOSYS

If that doesn't help you can try posting your issues on their forum:
http://www.candypress.com/CPforum/default.asp

-Jim

 

install cdont component