ASP.NET/MySQL Shopping Cart

brian.wolfe86 Peon

Messages:: 16

Likes Received:: 0

Best Answers:: 0

Trophy Points:: 0

#1

Hi,

I made the foolish mistake of developing my first ecommerce website in ASP.NET while using a MySQL database rather than Microsoft SQL Server...now, I'm faced with finding a shopping cart and have had little success.

Anyone know of any ASP.NET based shopping carts that support MySQL databases?

I found this one from Page Down Tech which supports ADO.NET connections and I saw that MySQL has a connector for ADO.NET, but didn't know if this was feasible or not.

http://www.pagedowntech.com/shopping_cart/storefront_highlights.asp

Also...if this is a pie-in-the-sky kind of idea, can I take a PHP based shopping cart and integrate it into my ASP.NET site?

Thanks in advance,

Brian

brian.wolfe86, Nov 27, 2008 IP

yugolancer Well-Known Member

Messages:: 320

Likes Received:: 8

Best Answers:: 0

Trophy Points:: 110

#2

I am afraid you cannot integrate PHP in ASP.NET.
Your best bet can be to create custom Shopping cart.
Actually i am really wondered that there is not shopping cart that supports mySQL.

The .NET Framework ships with Managed Data Providers for SQL Server (System.Data.
SqlClient namespaces), Oracle (System.Data.Oracle), OLE DB (System.Data.OleDb), and ODBC (System.Data.Odbc).

Therefore, you can keep your application as independent as possible to the backend database, using a trick to avoid using database-specific classes, such as sqlConnection, and so on.

Instead, you'll let the application decide at runtime which provider to use, depending on the connection string provided.

Means, the new ADO.NET 2.0 classes allow generic data access functionality (they werenâ€™t available in ADO.NET 1.0 or 1.1) - such as in DbConnection, DbCommand, and so on.
These classes are grouped under the System.Data.Common namespace.

HTH
Regards

yugolancer, Nov 27, 2008 IP

vihutuo Well-Known Member

Messages:: 1,511

Likes Received:: 34

Best Answers:: 0

Trophy Points:: 180

#3

You can use the built in profile provider to implement a quick shopping cart

vihutuo, Nov 28, 2008 IP

brian.wolfe86 Peon

Messages:: 16

Likes Received:: 0

Best Answers:: 0

Trophy Points:: 0

#4

Built in profile provider?

brian.wolfe86, Nov 28, 2008 IP

vihutuo Well-Known Member

Messages:: 1,511

Likes Received:: 34

Best Answers:: 0

Trophy Points:: 180

#5

Here is the shopping cart code that I use

Imports Microsoft.VisualBasic
Imports System.Collections.Generic

Namespace MyModules

<Serializable()> _
Public Class ShoppingCartItem

' ==========
' Private Variables
' ==========

Private _id As Integer = 0
Private _title As String = ""
Private _sku As String = ""
Private _unitPrice As Decimal
Private _quantity As Integer = 1

' ==========
' Properties
' ==========

Public Property ID() As Integer
Get
Return _id
End Get
Private Set(ByVal value As Integer)
_id = value
End Set
End Property

Public Property Title() As String
Get
Return _title
End Get
Private Set(ByVal value As String)
_title = value
End Set
End Property

Public Property SKU() As String
Get
Return _sku
End Get
Private Set(ByVal value As String)
_sku = value
End Set
End Property

Public Property UnitPrice() As Decimal
Get
Return _unitPrice
End Get
Private Set(ByVal value As Decimal)
_unitPrice = value
End Set
End Property

Public Property Quantity() As Integer
Get
Return _quantity
End Get
Set(ByVal value As Integer)
_quantity = value
End Set
End Property

' ==========
' Constructor
' ==========

Public Sub New(ByVal id As Integer, ByVal title As String, ByVal sku As String, ByVal unitPrice As Decimal, Optional ByVal Qty As Integer = 1)
Me.ID = id
Me.Title = title
Me.SKU = sku
Me.UnitPrice = unitPrice
Me.Quantity = Qty
End Sub
End Class

<Serializable()> _
Public Class ShoppingCart
Private _items As New Dictionary(Of Integer, ShoppingCartItem)()

Public ReadOnly Property Items() As ICollection
Get
Return _items.Values
End Get
End Property

' Gets the sum total of the items' prices
Public ReadOnly Property Total() As Decimal
Get
Dim sum As Decimal = 0.0
For Each item As ShoppingCartItem In _items.Values
sum += item.UnitPrice * item.Quantity
Next
Return sum
End Get
End Property

' Adds a new item to the shopping cart
Public Sub InsertItem(ByVal id As Integer, ByVal title As String, ByVal sku As String, ByVal unitPrice As Decimal, Optional ByVal Qty As Integer = 1)
If _items.ContainsKey(id) Then
_items(id).Quantity += Qty
Else
_items.Add(id, New ShoppingCartItem(id, title, sku, unitPrice, Qty))
End If
End Sub

' Removes an item from the shopping cart
Public Sub DeleteItem(ByVal id As Integer)
If _items.ContainsKey(id) Then
Dim item As ShoppingCartItem = _items(id)
item.Quantity -= 1
If item.Quantity = 0 Then _
_items.Remove(id)
End If
End Sub

' Removes all items of a specified product from the shopping cart
Public Sub DeleteProduct(ByVal id As Integer)
If _items.ContainsKey(id) Then
_items.Remove(id)
End If
End Sub

' Updates the quantity for an item
Public Sub UpdateItemQuantity(ByVal id As Integer, ByVal quantity As Integer)
If _items.ContainsKey(id) Then
Dim item As ShoppingCartItem = _items(id)
item.Quantity = quantity
If item.Quantity <= 0 Then _
_items.Remove(id)
End If
End Sub

' Clears the cart
Public Sub Clear()
_items.Clear()
End Sub
End Class

Public Class CurrentUserShoppingCart

Public Shared Function GetItems() As ICollection
Return CType(HttpContext.Current.Profile, ProfileCommon).ShoppingCart.Items
End Function

Public Shared Sub DeleteItem(ByVal id As Integer)
CType(HttpContext.Current.Profile, ProfileCommon).ShoppingCart.DeleteItem(id)
End Sub

Public Shared Sub DeleteProduct(ByVal id As Integer)
CType(HttpContext.Current.Profile, ProfileCommon).ShoppingCart.DeleteProduct(id)
End Sub
End Class

End Namespace
Click to expand...

Set up the membership schema with profiles. And add a new profile property through web.config
<add name="ShoppingCart" type="kcpita.ShoppingCart" serializeAs="Binary" allowAnonymous="true" />
To add items to the shopping cart

Profile.ShoppingCart.InsertItem(ItemID, ItemName, SKU, Price, Qty)
Click to expand...

vihutuo, Nov 28, 2008 IP

Halobitt likes this.

brian.wolfe86 Peon

Messages:: 16

Likes Received:: 0

Best Answers:: 0

Trophy Points:: 0

#6

Great, thanks for the code. I'll use that to port into my own custom shopping cart.

Brian

brian.wolfe86, Nov 30, 2008 IP

AstarothSolutions Peon

Messages:: 2,680

Likes Received:: 77

Best Answers:: 0

Trophy Points:: 0

#7

Creating a basic shopping cart is simple to do from scratch anyway. It is the one size fits all aspect of off the shelf that makes their programming so much more complex.

That said, if it has been written "correctly" with a DAL then it wouldnt be overly complex to rewrite just the data access elements in the .Net, it is recreating the SQL stored procs that is the pain in the arse part

AstarothSolutions, Dec 3, 2008 IP

Log in or Sign up

Advertising (learn more)

ASP.NET/MySQL Shopping Cart

brian.wolfe86 Peon

yugolancer Well-Known Member

vihutuo Well-Known Member

brian.wolfe86 Peon

vihutuo Well-Known Member

brian.wolfe86 Peon

AstarothSolutions Peon

Log in or Sign up

Advertising (learn more)

ASP.NET/MySQL Shopping Cart

brian.wolfe86 Peon

yugolancer Well-Known Member

vihutuo Well-Known Member

brian.wolfe86 Peon

vihutuo Well-Known Member

brian.wolfe86 Peon

AstarothSolutions Peon

Useful Searches